      REAL             FUNCTION SASUM( N, SX, INCX )
*
*     takes the sum of the absolute values.
*     uses unrolled loops for increment equal to one.
*     jack dongarra, linpack, 3/11/78.
*
*     .. Scalar Arguments ..
      INTEGER                          INCX, N
*     ..
*     .. Array Arguments ..
      REAL                             SX( 1 )
*     ..
*     .. Local Scalars ..
      INTEGER                          I, IX, M, MP1, NINCX
      REAL                             STEMP
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC                        ABS, MOD
*     ..
*     .. Executable Statements ..
*
      SASUM = 0.0E0
      STEMP = 0.0E0
      IF( N.LE.0 )
     $   RETURN
      IF( INCX.EQ.1 )
     $   GO TO 20
*
*        code for increment not equal to 1
*
      IX = 1
      IF( INCX.LT.0 )
     $   IX = 1 - ( N-1 )*INCX
      NINCX = IX + ( N-1 )*INCX
      DO 10 I = IX, NINCX, INCX
         STEMP = STEMP + ABS( SX( I ) )
   10 CONTINUE
      SASUM = STEMP
      RETURN
*
*        code for increment equal to 1
*
*
*        clean-up loop
*
   20 M = MOD( N, 6 )
      IF( M.EQ.0 )
     $   GO TO 40
      DO 30 I = 1, M
         STEMP = STEMP + ABS( SX( I ) )
   30 CONTINUE
      IF( N.LT.6 )
     $   GO TO 60
   40 MP1 = M + 1
      DO 50 I = MP1, N, 6
         STEMP = STEMP + ABS( SX( I ) ) + ABS( SX( I+1 ) ) +
     $           ABS( SX( I+2 ) ) + ABS( SX( I+3 ) ) +
     $           ABS( SX( I+4 ) ) + ABS( SX( I+5 ) )
   50 CONTINUE
   60 SASUM = STEMP
      RETURN
      END
